grid 控件示例

下面的示例在表单上设置表格控制。首先打开 customer 表，并在表格中显示其内容，然后使用 caption 属性为 cust_id 字段指定另一个标头标题 (customer id)，最后在表单上设置关闭表单的命令按钮。使用 setall 方法设置 dynamicbackcolor 属性以指定记录的背景色。如果表格中显示的记录编号为偶数，则记录的 dynamicbackcolor 为白色，否则记录的 dynamebackcolor 为绿色。

close all && 关闭表和数据库
open database (home( ) + 'samples\data\testdata')

use customer in 0 && 打开 customer 表

frmmyform = createobject('form') && 创建“表单”
frmmyform.closable = .f. && 废止“控制”菜单框

frmmyform.addobject('cmdcommand1','cmdmycmdbtn') && 添加命令按钮
frmmyform.addobject('grdgrid1','grid') && 添加“表格”控制

frmmyform.grdgrid1.left = 25 && 调整“表格”位置

frmmyform.grdgrid1.setall("dynamicbackcolor", ;
"iif(mod(recno( ), 2)=0, rgb(255,255,255) ;
, rgb(0,255,0))", "column") && 交替显示白色和绿色的记录

frmmyform.grdgrid1.visible = .t. && “表格”控制可见
frmmyform.cmdcommand1.visible =.t. && 使“退出”命令按钮可见
frmmyform.grdgrid1.column1.header1.caption = 'customer id'

frmmyform.show && 显示表单
read events && 启动事件处理

define class cmdmycmdbtn as commandbutton && 创建命令按钮
caption = '\<quit' && 命令按钮上的标题
cancel = .t. && 默认“取消”命令按钮(esc)
left = 125 && 命令按钮的列
top = 210 && 命令按钮的行
height = 25 && 命令按钮的高度

procedure click
clear events && 终止事件处理，关闭“表单”
close all && 关闭表和数据库
enddefine