下面的示例使用 dynamicbackcolor 属性和 setall 方法指定表格控制中记录的背景颜色。若显示在表格中的记录号为偶数,则该记录的 dyamicbackcolor 是白色,否则 dynamicbackcolor 是绿色。在表单上放置一个表格控制后,打开 customer 表并且在表格上显示该表的内容。caption 属性用来为 cust_id 字段指定不同的标头标题。在表单上放置一个命令按钮来关闭表单。
close all && 关闭表和数据库
open database (home( ) + 'samples\data\testdata')
use customer in 0 && 打开 customer表
frmmyform = createobject('form') && 创建表单
frmmyform.closable = .f. && 使控制菜单框无效
frmmyform.addobject('cmdcommand1','cmdmycmdbtn') && 添加命令按钮
frmmyform.addobject('grdgrid1','grid') && 添加表格控制
frmmyform.grdgrid1.left = 25 && 调整表格位置
frmmyform.grdgrid1.setall("dynamicbackcolor", ;
"iif(mod(recno( ), 2)=0, rgb(255,255,255) ;
, rgb(0,255,0))", "column") && 交替白色和绿色记录
frmmyform.grdgrid1.visible = .t. && 表格控制可见
frmmyform.cmdcommand1.visible =.t. && “退出”命令按钮可见
frmmyform.grdgrid1.column1.header1.caption = 'customer id'
frmmyform.show && 显示表单
read events && 启动事件处理
define class cmdmycmdbtn as commandbutton && 创建命令按钮
caption = '\<quit' && 命令按钮上的标题
cancel = .t. && 默认取消命令按钮(esc)
left = 125 && 命令按钮的列
top = 210 && 命令按钮的行
height = 25 && 命令按钮的高度
procedure click
clear events && 结束事件处理,关闭表单
close all && 关闭表和数据库
enddefine