for each … endfor 命令示例

以下示例演示了如何使用 for each 语句枚举visual foxpro 数组中的元素、一个ole 数组和赋给对象数组的一套命令按钮。

以下示例中创建了一个 visual foxpro 变量并使用 for each 语句显示数组中每个元素的内容。

dimension cmyarray(3)
cmyarray[1] = 'a'
cmyarray[2] = 'b'
cmyarray[3] = 'c'
for each cmyvar in cmyarray
   ? cmyvar
endfor

在以下示例中，创建了一个 microsoft excel 实例，添加了一个新的工作簿。使用 foreach 语句显示工作簿中每个工作表的名称。此示例要求在运行示例的机器上正确安装 microsoft excel。

oexcel = create("excel.application")
oexcel.workbooks.add
for each omyvar in oexcel.sheets
   ? omyvar.name
next omyvar

在以下示例，在表单放置了五个命令按钮。使用 for each 命令显示表单上的按钮并指定它们的标题、字体和每个按钮的位置。

public omyobject
omyobject = createobject("frmtest")
omyobject.show
define class frmtest as form
height = 200
dimension myarray[5]
   procedure init
      for i = 1 to 5
         this.addobject('this.myarray[i]',;
            'commandbutton')
      endfor      
      ****** for each - next ******
      for each obutton in this.myarray
         obutton.visible = .t.
      next
      
      ****** for each - next element  ******
      for each obutton in this.myarray
         obutton.fontbold = .t.
      next obutton
      j = 1
      ****** for each - endfor ******
      for each obutton in this.myarray
         obutton.top = j * 30
         j = j + 1
      endfor   
      
      ****** for each - endfor element ******
      for each obutton in this.myarray
         obutton.fontitalic = .t.
      endfor obutton
      
      j = 1
      ****** exit  ******
      for each obutton in this.myarray
         obutton.caption = "test" + str(j)
         j = j+1
         if j > 3 
            exit
         endif
      next
      
      j = 1
      ****** loop  ******
      for each obutton in this.myarray
         if j > 3
            loop
         endif
         j = j + 1
         obutton.left = 25
      next
   endproc
enddefine