下面的示例演示了如何使用 left 属性确定控制在表单中的位置。使用 addobject 方法向表单中添加一个线条控制和三个命令按钮，left 属性指定了表单上每个控制的水平位置。
frmmyform = createobject('form') && 创建一个表单
frmmyform.closable = .f. && 废止控制菜单框
frmmyform.addobject('shpline','line') && 向表单中添加线条控制
frmmyform.addobject('cmdcmndbtn1','cmdmycmndbtn1') && “向上”命令按钮
frmmyform.addobject('cmdcmndbtn2','cmdmycmndbtn2') && “向下”命令按钮
frmmyform.addobject('cmdcmndbtn3','cmdmycmndbtn3') && “退出”命令按钮
frmmyform.shpline.visible = .t. &&使线条控制可见
frmmyform.shpline.top = 20 && 指定线条控制行
frmmyform.shpline.left = 125 &&指定线条控制列
frmmyform.cmdcmndbtn1.visible =.t. && “向上”命令按钮可见
frmmyform.cmdcmndbtn2.visible =.t. && “向下”命令按钮可见
frmmyform.cmdcmndbtn3.visible =.t. && “退出” 命令按钮可见
frmmyform.show && 显示表单
read events && 开始事件处理
define class cmdmycmndbtn1 as commandbutton && 创建命令按钮
caption = 'slant \<up' && 命令按钮标题
left = 50 && 命令按钮行
top = 100 && 命令按钮列
height = 25 && 命令按钮高度
procedure click
thisform.shpline.visible = .f. && 隐藏线条控制
thisform.shpline.lineslant ='/' && 斜向上
thisform.shpline.visible = .t. && 显示线条控制
enddefine
define class cmdmycmndbtn2 as commandbutton && 创建命令按钮
caption = 'slant \<down' && 命令按钮标题
left = 200 && 命令按钮行
top = 100 && 命令按钮列
height = 25 && 命令按钮高度
procedure click
thisform.shpline.visible = .f. &&隐藏线条控制
thisform.shpline.lineslant ='\' && 斜向下
thisform.shpline.visible = .t. && 显示线条控制
enddefine
define class cmdmycmndbtn3 as commandbutton && 创建命令按钮
caption = '\<quit' && 命令按钮标题
cancel = .t. && 默认取消命令按钮(esc)
left = 125 && 命令按钮行
top = 150 && 命令按钮列
height = 25 && 命令按钮高度
procedure click
clear events && 结束事件处理，关闭表单
enddefine