第三十三章：对编程的改进

Microsoft Visual FoxPro 现在包含了一些新的编程功能，可以提高开发效率。这些功能包括 Access 和 Assign 方法程序，用于在查询属性值、或试图更改属性值时执行代码；软件现支持更多的图形文件格式、以及新的简化编程任务的语言。另外，还在 Visual FoxPro API 库文件 Foxtools.fll 中添加了很多文件名使用函数。

本章主要内容∶

• Access 和 Assign 方法程序
  
  
• 对 GIF 和 JPEG 图形的支持
  
  
• 新的和改进的语言元素
  
  
• 对 2000 年日期的支持

Access 和 Assign 方法程序

Visual FoxPro 已得到改进，现支持 Access 和 Assign 方法程序。在查询属性值、或试图更改属性值时，可使用这些用户自定义的方法程序来执行代码。

在查询属性值时，将执行 Access 方法程序中的代码。通常可以通过在一个对象的引用中使用属性、将属性值保存到一个变量中或使用问号 (?) 显示属性的值。

在试图更改属性值时，将执行 Assign 方法程序中的代码。通常可以通过使用 STORE 或 = 命令为属性赋予一个新值。

只有在运行时刻查询或更改属性值，才执行 Access 和 Assign 方法程序。在设计时刻查询或更改属性值，不会执行 Access 和 Assign 方法程序。

注释 由于赋予的属性值将传递到 Assign 方法程序，因此在 Assign 方法程序中必须包含 PARAMETERS 或 LPARAMETERS 语句，以便接收该值。

可以分别创建 Access 和 Assign 方法程序 — 即可以创建一个 Access 方法程序，而不创建 Assign 方法程序；或者创建一个 Assign 方法程序，而不创建 Access 方法程序。

可为那些使用 DEFINE CLASS 语句所创建的属性来创建 Access 和 Assign 方法程序，或使用表单和类设计器交互地为表单或类创建 Access 和 Assign 方法程序。

注释 也可以为 Visual FoxPro 所有固有的属性创建 Access 和 Assign 方法程序。例如，可以为表单的 Left 属性创建 Access 方法程序，以便在查询表单的 Left 属性的时候执行代码；也可以为只读的 Visual FoxPro 固有属性（如，ParentClass 属性）创建 Assign 方法程序，但该方法程序永远也不会执行。

Access 和 Assign 方法程序的优点

Access 和 Assign 方法程序提供下列优点∶

• 为将接口和实现分开的类或对象创建一个公共接口。
  
  
• 可轻松对属性的有效性进行确认。
  
  
• 便于保护子类 ActiveX 控件的属性。

创建 Access 和 Assign 方法程序

通过对 DEFINE CLASS 命令、表单和类设计器的改进，可以使用编程和交互方式来创建 Access 和 Assign 方法程序。

新 DEFINE CLASS 后缀

DEFINE CLASS 命令添加了两个后缀 _ACCESS 和 _ASSIGN，可用于创建 Access 和 Assign 方法程序。在函数或过程的名称后面添加这些后缀将为属性创建一个 Access 或 Assign 方法程序，且方法程序的名称与函数或过程相同。

例如，下列示例代码使用 DEFINE CLASS 创建了一个名为 MyClass 的自定义类，并为其创建了一个用户定义的属性 MyProperty，然后使用 PROCEDURE 语句为 MyProperty 创建了一个 Access 方法程序。

在查询属性值时，将执行过程中的代码 (WAIT WINDOW 'This is the Access method')。用 PROCEDURE 语句也可以为 MyProperty 创建了一个 Assign 方法程序。在更改属性值时，将执行过程中的代码 (WAIT WINDOW 'This is the Assign method')。

请注意，示例中使用了 LPARAMETERS 语句来接受传递到 Assign 方法程序的值，本示例还演示了如何创建只读属性。

DEFINE CLASS MyClass AS Custom
   MyProperty = 100 && A user-defined Property

   PROCEDURE MyProperty_ACCESS && Access method
      WAIT WINDOW 'This is the Access method ';
          +  ' ' + PROGRAM( )
      RETURN THIS.MyProperty
   ENDPROC

   PROCEDURE MyProperty_ASSIGN && Assign method
      LPARAMETERS tAssign  && Required to accept value
      WAIT WINDOW 'This is the Assign method ';
          + ' ' + PROGRAM( )
   ENDPROC
ENDDEFINE

下面的示例演示了如何为固有的 Visual FoxPro 属性添加 Assign 方法程序，并对设置的属性进行简单的有效性确认。请注意，本示例只创建了一个 Assign 方法程序，而没有相应的 Access 方法程序。

本例使用 DEFINE CLASS 创建了一个名为 frmMyForm 的 Form 类，用 PROCEDURE 语句创建了一个名为 Left_ASSIGN 的 Assign 方法程序，在为表单的 Left 属性指定值时，将执行 Assign 方法程序中的代码。

如果试图将 Left 属性值改为负值，将显示一条警告信息，Left 属性值保持不变。如果将 Left 属性值改为非负值，Left 属性值将被设置成这个值。

DEFINE CLASS frmMyForm AS Form

 PROCEDURE Left_ASSIGN && Assign method
      LPARAMETERS tAssign  && Required to accept value
      
      DO CASE
         CASE tAssign < 0 && Left value negative
            WAIT WINDOW 'Value must be greater than 0'
         OTHERWISE  && Left value not negative
            THIS.Left = tAssign
      ENDCASE
   ENDPROC
ENDDEFINE

有关创建 Access 和 Assign 方法程序的语法的详细内容，请参阅 DEFINE CLASS。

表单和类设计器

若要在“表单设计器”中创建 Access 或 Assign 方法程序

1. 选取“表单”菜单中的“新建属性”命令。

   将显示“新建属性”对话框。

   

2. 在“名称”文本框中输入需要创建的属性的名称，然后选取“Access 方法程序”复选框或“Assign 方法程序”复选框（或两个都选）。
   
   
3. 选取“添加”为表单创建一个属性，并为该属性创建 Access 或 Assign 方法程序。

若要在“表单设计器”中为 Visual FoxPro 的原有属性创建 Access 或 Assign 方法程序

1. 从“表单”菜单选择“新建方法程序”。

   将显示“新建方法程序”对话框。

2. 在“名称”文本框中输入方法程序名，其原来的属性后面接 _Access 或 _Assign。例如，若要创建 Left 属性的 Access 方法程序，只需在“名称”文本框中输入“Left_Access”。
   
   
3. 选取“添加”，将创建原有属性的 Access 或 Assign 方法程序。

注释 在“表单设计器”中，只能为表单或表单集创建带有 Access 和 Assign 方法程序的属性。如果需要为控件或对象创建带有 Access 和 Assign 方法程序的属性，则可使用类设计器来创建该控件或对象的类。在“类设计器”中，将带有 Access 和 Assign 方法程序的属性添加到控件或对象中，然后在“表单设计器”中将控件或对象添加到表单中。

若要在“类设计器”中为类创建 Access 或 Assign 方法程序

1. 从“类”菜单中选取“新建属性”命令。

   将显示“新建属性”对话框。

2. 在“名称”文本框中键入需要创建的属性的名称，然后选取“Access 方法程序”复选框或“Assign 方法程序”复选框（或两个都选）。
   
   
3. 选取“添加”，为该类创建一个属性，并且为该属性创建 Access 或 Assign 方法程序。

有关创建 Access 或 Assign 方法程序的详细内容，请参阅“新建属性”对话框主题。

THIS_ACCESS 方法程序

Visual FoxPro 6.0 中添加一个新的全局的类方法程序，即 THIS_ACCESS。在更改对象成员的值、或查询对象的成员时，将执行 THIS_ACCESS 方法程序中的代码。

THIS_ACCESS 方法程序可通过执行 DEFINE CLASS 命令创建、或通过 .vcx 可视类库的“新建方法程序”或“编辑属性”对话框创建。THIS_ACCESS 方法程序必须返回一个对象引用，否则将产生错误。通常情况下，该方法程序返回 THIS 对象引用。THIS_ACCESS 方法程序还必须包含一个参数，接收被更改或查询的成员的名称。

下列的示例演示了如何在 DEFINE CLASS 命令中创建一个 THIS_ACCESS 方法程序。当示例作为程序运行时，“Caption”将显示两次，第一次是在为 Caption 属性赋值时，第二次是在查询 Caption 属性的值。最后将显示 Caption 的属性的值 ('abc')。

CLEAR
oTempObj = CREATEOBJECT('MyForm')  && Instantiate the Form
oTempObj.Caption = 'abc'  && Assign a value, triggers THIS_ACCESS
? oTempObj.Caption  && Query a value, triggers THIS_ACCESS

DEFINE CLASS MyForm AS Form
 PROCEDURE THIS_ACCESS
      LPARAMETER cMemberName  && Object member name

      IF cMemberName = 'caption'
         ? cMemberName  && Display the Object member name
      ENDIF
      RETURN THIS
   ENDPROC
ENDDEFINE

请注意，THIS_ACCESS 并不是要在全局范围内替换 Access 和 Assign 方法程序 - 而只是提供有关被访问或查询的对象成员的信息。与 Access 或 Assign 方法程序不同，THIS_ACCESS 不提供对返回值（返回给特定对象成员）的控制。

Access 和 Assign 方法程序的编程注意事项

下文描述有关 Access 和 Assign 方法程序编程的信息。

作用域

默认时，Access 和 Assign 方法程序是被保护的 - 即在创建 Access 或 Assign 方法程序的类外，不能访问或更改 Access 或 Assign 方法程序。

如果在创建 Access 或 Assign 方法程序时包含 HIDDEN 关键字，可防止在类定义以外访问和更改属性。只有类定义中的方法程序才能访问隐藏的属性。虽然类定义的子类可以访问被保护的属性，但只能在类定义中访问隐藏的属性。

注释 如果不包含 HIDDEN 关键字，将创建 Access 和 Assign 方法程序的子类。

调试

在“Visual Foxpro 调试器”窗口的“跟踪”窗口中，可以查看 Access 和 Assign 方法程序中的代码。但不能在“Visual Foxpro 调试器”窗口的“监视”和“局部”窗口中执行 Access 和 Assign 方法程序。

向 Assign 方法程序传递数组

向 Access 和 Assign 方法程序传递数组的方式与标准的 Visual FoxPro 传递过程相同。

如果发出 SET UDFPARMS TO REFERENCE 命令、或在数组名称之前加 @ 前缀，则向 Access 和 Assign 方法程序传递整个数组。如果发出 SET UDFPARMS TO VALUE 命令、或用括号括上数组的名称，则向 Access 和 Assign 方法程序传递数组的第一个元素。有关传递值和数组的详细内容，请参阅 SET UDFPARMS。

ActiveX 控件

ActiveX 控件的固有属性、事件或方法程序不支持 Access 和 Assign 方法程序。但对于包含 ActiveX 控件的 Visual FoxPro OLE 容器，其属性、事件和方法程序支持 Access 和 Assign 方法程序。

ResetToDefault 方法程序

对 Access 或 Assign 方法程序执行 ResetToDefault 方法程序，将使 Access 或 Assign 方法程序中的代码成为默认的代码片段，造成继承的代码得不到执行。本技术可用来确保根据方法程序的类型来执行从父类继承的代码。

将下列代码放在一个 Access 方法程序的子类中，以执行父类中的代码∶

RETURN DODEFAULT( )

将下列代码放在一个 Assign 方法程序的子类中，以执行父类中的代码∶

LPARAMETERS vnewval
DODEFAULT(vnewval)
THIS.<property name> = vnewval

将下列代码放在一个 THIS_ACCESS 方法程序的子类中，以执行父类中的代码∶

LPARAMETERS cmember
RETURN DODEFAULT(cmember)

对 GIF 和 JPEG 图形的支持

Visual FoxPro 已得到改进，能够支持 GIF (Graphics Interchange Format) 和 JPEG (Joint Photographic Electronic Group) 图形文件格式，这两种格式在 Internet 上应用广泛。

通常，在早期版本的 Visual FoxPro 中，任何支持 .bmp (bitmap) 格式的地方也支持下列图形文件格式。

注释 在 Visual FoxPro 中，光标、动画光标和图标文件也用作图形文件。例如，对于 Image 控件（图象控件），可以将 Picture 属性指定为一个动画光标文件（但是，图象控件只显示其静态图像）。

Visual FoxPro 中有三个领域支持图形∶语言、控件和对象，以及界面。

Visual FoxPro 语言

下列命令和函数已得到改进，现支持新的图形文件格式。

GETPICT( )

通过在“命令”窗口使用 GETPICT( ) 函数，可以显示“打开图片”对话框，该对话框已得到改进，可快速定位所有 Visual FoxPro 支持的图形文件。“文件类型”下拉式列表现包含下列项。

选中“预览”复选框可显示当前选中的图形文件，而在早期版本的 Visual FoxPro 中，在选择新的图形文件时，需要选取“预览”按钮。此外，“图片”区的面积也增加了。

CLEAR RESOURCES

使用 Visual FoxPro 的 CLEAR RESOURCES 命令可清除所有缓存的图形文件，包括 .gif 和 .jpg 文件。

Visual FoxPro 控件和对象

下表列出了可将其属性指定为图形文件 Visual FoxPro 的控件和对象。除早期 Visual FoxPro 版本所支持的 .bmp 和 .dib 图形文件外，还可指定 .gif、.jpg、光标、动画光标和图标等图形文件。

Visual FoxPro 界面

使用几种 Visual FoxPro 设计器的“打开”对话框可以指定图形文件。下列设计器的“打开”对话框得到改进，可包含新的图形文件格式。

表单设计器和类设计器

在“属性”窗口中双击一个支持图形文件的属性、或选取属性的对话框按钮，可显示“打开”对话框。

项目管理器

在项目管理器的“全部”和“其他”选项卡中，可以向一个项目添加图形文件。选取“全部”、或“其他”选项卡后，选取“其他文件”项，然后选取“添加”，将显示“添加”对话框，在此可向项目中添加图形文件。

报表设计器

“报表控件”工具栏包含“图片/ActiveX 绑定控件”按钮。单击该按钮，并将鼠标光标拖到报表设计器的一个带区，将显示“报表图片”对话框。选取“文件”对话框按钮将显示“打开”对话框。

新的和改进的语言元素

Visual FoxPro 中添加了许多新的和改进的语言元素。本节列出的新的语言元素有 Active Documents、项目管理器挂接、OLE 拖放、服务程序语言的改进 和什锦语言。

同时还列出了改进了的语言元素。

此外，Visual FoxPro API 库文件 Foxtools.fll 中有很多文件名使用函数，该库现已添加到 Visual FoxPro 中。因此，不必使用 SET LIBRARY TO FOXTOOLS.FLL 命令来调用 Foxtools 函数，可在 Visual FoxPro 程序中直接调用这些函数。

本节描述 Visual FoxPro 在性能、坚固性和实用性等方面的提高。

Visual FoxPro 性能的提高

在 Visual FoxPro 6.0 中，字符连接的性能有了极大的提高。字符连接通常可用来创建 Web 页，如下列代码所示∶

cMyString = cMyString + <html tags>
cMyString = cMyString + <more html tags>
cMyString = cMyString + <even more html tags>

另外，对象创建和实例化性能也提高了许多，通常较早期版本提高了 10 倍或更多。

Visual FoxPro 坚固性的提高

Visual FoxPro 6.0 可以截取表单上 ActiveX 控件的 General Protection Faults (GPFs) 或在 Visual FoxPro 中实例化的 COM 对象的 General Protection Faults (GPFs)。ActiveX 控件或 COM 对象的 GPF 现被认为是可捕捉的 Visual FoxPro 错误（错误 1440 - OLE 对象可能已被破坏）。

Visual FoxPro 实用性的提高

可以在 Windows 注册表中指定 Visual FoxPro 编辑器注释字符串。方法是：使用 Windows Registry Editor (RegEdit)，打开 Visual FoxPro 6.0 的 Options 文件夹，在该文件夹上单击鼠标右键。选取“新建”，然后选取“串值”并键入“EditorCommandtring”作为新的字符串值；在该字符串值上单击鼠标右键，然后选取“修改”并键入编辑器注释字符串（如果注册表中没有该注册项时，*!* 为默认值）。

现在，即可在表单代码窗口中访问“表单”菜单。此外，即使在表单代码窗口中，也可以使用 CTRL+E 键盘快捷键运行表单。

对 2000 年日期的支持

Visual FoxPro 6.0 已得到改进，可提供对 2000 年日期的更好的支持。本节描述一些 Visual FoxPro 的改进，使用这些改进可以更容易地创建与 2000 年日期相兼容的应用程序。

SET CENTURY TO

Visual FoxPro 5.0 的文档声称，在不带附加参数的情况下发出 SET CENTURY TO 命令，则将世纪设置成当前世纪。这只在二十世纪是正确的，因为不管当前世纪是什么，世纪值都设置为 19。而在 Visual FoxPro 6.0 中，SET CENTURY TO 命令会将世纪值设置为当前世纪。此外，在新的数据工作期，SET CENTURY TO 的值将被初始化为当前世纪。

另外，在 Visual FoxPro 6.0 中，SET CENTURY 的 ROLLOVER 默认值已更改为当前年份的最后两个数字加 50 年。也就是说，如果当前是 1998 年，nYear 是 48，48 即 2048 (1998 + 50) 的最后两个数字。在 Visual FoxPro 5.0 中，这个默认值为 0。

详细内容，请参阅 SET CENTURY。

严格的日期格式

通常情况下，对 Date 和 DateTime 常数或表达式进行编译或估算时，是根据 SET DATE 和 SET CENTURY 的当前设置进行对其解释的。这意味着，由于日期常数编译时间的不同、以及在编译时起作用的日期设置的不同，日期常数可能被估算成不同的值，因此很多日期常数是不确定的。

例如，日期常数 {10/11/12} 是 1912 年 10 月 11 日、2012 年 10 月 11 日、1912 年 11 月 10 日、1910 年 11 月 12 日，还是 2010 年 11 月 12 日？

这完全取决于 SET DATE 和 SET CENTURY TO 的当前设置。在编译 Date 和 DateTime 常数或表达式、或在运行时刻估算其值（如在报表和对象的表达式中）时，都会将错误带入现有的 Visual FoxPro 代码。如果将 SET CENTURY 设置设定成 2000 年，而没有指定四位数字的年份时，将会给现有代码带来 2000 年不兼容的错误。

为了避免这种不兼容性，在 Visual FoxPro 6.0 （以及 Visual FoxPro 5.0）中使用了一种严格的日期格式。无论对于何种日期设置，这种严格的日期格式都能计算出相同的 Date 或 DateTime 值。该日期格式是∶

^yyyy-mm-dd[,][hh[:mm[:ss]][a|p]]

(^) 符号表明该格式是严格的日期格式，并按照 YMD 的格式解释 Dates 和 DateTimes。有效的 Date 和 DateTime 分隔符位连字符、正斜杠、句点和空格。

空 Dates 和 DateTimes 被认为是明确的、且总是有效的。有效的空 Date 和 DateTime 格式包括 {}、{--} 和 {--,:}。

有了严格的日期格式，就可以使用多种可用的 Date 和 DateTime 值。在 Visual FoxPro 5.0 中，最小的日期值是 {^0100/1/1}，即公元 100 年 1 月 1 日，这是由于小于 100 的年份值都将根据 SET CENTURY 的设置被四舍五入为最近的世纪值。

在 Visual FoxPro 6.0 中，最小的日期值是 {^0001-01-01}，即公元 1 年 1 月 1 日。在 Visual FoxPro 6.0 中，最大的日期值是 {^9999-12-31}，即公元 9999 年 12 月 31 日。

严格格式的 Date 或 DateTime 总是符合 Western 日历的（注意，在 Visual FoxPro 5.0 中与此不同）。

SET STRICTDATE

在 Visual FoxPro 6.0 中，一个新命令，SET STRICTDATE 可用来增强日期常数和日期字符串的 2000 年兼容性。

SET STRICTDATE TO 0

将 STRICTDATE 设置为 0 意味着不进行严格日期格式的检查。这与 Visual FoxPro 5.0 兼容的。运行时刻 Visual FoxPro 和 ODBC 驱动程序的默认设置为 0。如果 STRICTDATE 设置为 0，无效的 Date 和 DateTimes 将作为空日期。

SET STRICTDATE TO 1

将 STRICTDATE 设置为 1，意味着要求所有 Date 和 DateTime 常数都符合严格的日期格式。不论是在编译、运行时刻或在一个交互的 Visual FoxPro 工作期，任何不符合严格格式的 Date 或 DateTime 常数（或被估算为无效值）都将生成一个错误。交互的 Visual FoxPro 工作期的默认设置为 1。

SET STRICTDATE TO 2

与将 STRICTDATE 设置为 1 相同，但如果 CTOD( ) 和 CTOT( ) 函数出现在代码中，将产生编译错误（错误 2033 -CTOD 和 CTOT 会产生不正确的结果）。

由于 CTOD( ) 和 CTOT( ) 的返回值需要使用 SET DATE 和 SET CENTURY 的设置来解释函数中所包含的日期字符串，因此易于出现与 2000 年不兼容的错误。请使用带有可选的数值参数的 DATE( ) 和 DATETIME( ) 创建 Date 和 DateTime 常数和表达式。

这个设置最适合在调试时使用，用来捕捉可能包含 2000 年兼容性错误的代码。

严格日期格式错误

Visual FoxPro 6.0 中添加了下列新的错误，并当 SET STRICTDATE 设置为 1 或 2 时，发生这些错误。

错误 2032∶不明确的日期/日期时间常量。

当 Date 或 DateTime 不符合严格格式时，将发生该错误。下面的情况会产生这种错误：

• 无 (^) 符号。
  
  
• 日期分隔符不是连字符、正斜杠、句点或空格。
  
  
• 年份域包含的值小于四个字符（例如{^98-02-16}）。
  
  
• 月份或日期域是空的（例如{^1998-02})。

错误 2033∶CTOD 和 CTOT 会产生不正确的结果。

这个错误发生的原因与错误 2032 相同，但是 CTOD( ) 和 CTOT( ) 也可能造成日期的不兼容或不明确。请使用 DATE( ) 或 DATETIME( ) 函数。

错误 2034∶日期/日期时间计算为无效值。

Date 或 DateTime 值不符合有效的 Date 或 DateTime 格式、或超出有效的 Date 或 DateTime 范围。

当 SET STRICTDATE 被设置为 0 时，无效的 Date 和 DateTime 常数将被估算为空的 Date 或 DateTime。而当 SET STRICTDATE 被设置为 1 或 2 时，无效的常数将产生这个错误，例如 {^2000-02-31}（2 月 31 日）或者 {^2000-01-01,25:00}（25 点）。

无效 Dates 和 DateTimes 的示例如下∶

• {^2000-02-31}，2000 年 2 月 31 日。
  
  
• {^2000-01-01,25:00}，25 点。
  
  
• {^2000-01-01, 14a}，上午 14 点。

错误 2035∶日期/日期时间中包含了非法字符。

Date 或 DateTime 常数包含 Date 和 DateTime 常数不支持的字符。

当 SET STRICTDATE 被设置为 0 时，包含非法字符的 Date 或 DateTime 常数将被估算为空的 Date 或 DateTime。而当 SET STRICTDATE 被设置为 1 或 2 时，包含非法字符的 Date 或 DateTime 常数将产生这个错误。

请注意，StrictDateEntry 属性不受 SET STRICTDATE 设置的影响。在 Visual FoxPro 6.0 中，StrictDateEntry 属性保持不变。

“选项”对话框

“选项”对话框的“常规”选项卡包含一个“2000 年兼容性”下拉列表，用于指定 SET STRICTDATE 的设置。与所有其他“选项”对话框的项目相同，这里设置的值是为当前 Visual FoxPro 工作期设置的，选取“设置为默认值”按钮，则将该设置保存在 Windows 注册表中，以后的 Visual FoxPro 工作期都可使用。

DATE( ) 和 DATETIME( ) 函数

DATE( ) 和 DATETIME( ) 函数现支持可选的数值参数，可用来创建与 2000 年兼容的 Date 或 DateTime 值。对这些函数的加强，为创建 Date 和 DateTime 值提供了一种更优越的方法；因此不再需要使用字符进程函数来创建 Date 和 DateTime 值。

FDATE( ) 函数

FDATE( ) 函数现支持可选的数值参数，可用来确定文件的最后修改日期，而无须使用字符进程函数。例如，在早期版本的 Visual FoxPro 中，需要编写如下代码，来确定 Visual FoxPro 源文件的最后修改日期∶

tLastModified = CTOT(DTOC(FDATE('Foxuser.dbf')) + ' ' ;
   + FTIME('Foxuser.dbf') 

现在，这些代码现在可以替换为∶

tLastModified = FDATE('Foxuser.dbf', 1)

Century 属性

在 Visual FoxPro 6.0 中，Century 属性的默认设置为 1 - 开。日期的世纪部分显示在一个文本框中。在早期版本的 Visual FoxPro 中，其默认值是 2 - 设定世纪，该设置确定是否显示日期的世纪部分。